Re: Creating several types from a base type and conversion

[Bill Findlay <findlaybill@blueyonder.co.uk>]

On 18 Jan 2020, Simon Wright wrote
(in article <lyftgcy059.fsf@pushface.org>):

> "Jeffrey R. Carter"<spam.jrcarter.not@spam.not.acm.org>  writes:
>
> > On 1/18/20 7:20 PM, Bill Findlay wrote:
>
> > > type word is mod 2**30;
> > >
> > > subtype word_shift_length is Natural range 0..30;
> > >
> > > function shift_word_left (W : word; amount : word_shift_length)
> > > return KDF9.word;
>
> > I don't know what KDF9.Word is, but surely you have to implement
> > these. Or are you saying GNAT magically implements them?
>
> It doesn't; 'with Import, convention =>  Intrinsic' requires the first
> argument to have size 8, 16, 32, or 64, and the second argument must be
> Natural (not a subtype of it, even if unconstrained).

D'oh! (Looks around for lost marbles - they are here somewhere.)

Here are extracts from theactual code for KDF9's 48-bit shift operations,
showing how they are built up from the intrinsic 64-bit shifts.
Converting this to 30-bit shifts using 32-bit intrinsics should be simple:

-- 
-- The fundamental emulated storage unit is the 48-bit word.
-- 

type word is mod 2**48;

-- 
-- This is the emulation host's 64-bit unsigned integer type.
-- 

type u_64 is mod 2**64 with Size =>  64;

word_mask : constant := 8#7777777777777777#;

function as_word (u : u_64)
return word
is (word(u and word_mask));

-- This GNAT-specific pragma declares all the 64-bit shift operations.

pragma Provide_Shift_Operators (u_64);

-- 
-- These are the 48-bit primitive, fixed-direction, shift operations.
-- 

subtype word_shift_length is Natural range 0..48;

function shift_word_left (W : word; amount : word_shift_length)
return word
is (as_word(shift_left(u_64(W), amount)));

function shift_word_right (W : word; amount : word_shift_length)
return word
is (word(shift_right(u_64(W), amount)));

function rotate_word_left (W : word; amount : word_shift_length)
return word
is (shift_word_left(W, amount) or shift_word_right(W, 48-amount));

function rotate_word_right (W : word; amount : word_shift_length)
return word
is (shift_word_right(W, amount) or shift_word_left(W, 48-amount));

-- 
-- KDF9 shift operations actually had a signed shift amount; e.g.:
-- 

function shift_logical (W : word; L : signed_Q_part)
return word
is
(
if abs L >  47 then 0
elsif L <  0 then shift_word_right(W, Natural(-L))
else shift_word_left (W, Natural(+L))
);

... etc ...

Sorry for the temporary brain malfunction!

-- 
Bill Findlay